ProcessingJP

2月25日 Processingの新しいバージョンである 2.0 beta 8 がリリースされました。
Download \ Processing.org
今回は、特に注目すべきポイントについてご紹介します。

• Retinaディスプレイがサポートされ、パフォーマンスが改善されています。
• その他複数のバグが修正されています。

final int RATIO = 10;
float x, y;
PGraphics g1, g2;
int SIDE=200;
int WIDTH=SIDE*2, HEIGHT=SIDE;

void setup() {
  frameRate(1000);
  clear();//more than 2.0b8 (If less than 2.0b7 background(0, 0, 0, 0))
  size(WIDTH, HEIGHT);
  stroke(255);

  g1 = createGraphics(SIDE, SIDE);
  g1.beginDraw();
  g1.clear();//more than 2.0b8 (If less than 2.0b7 background(0, 0, 0, 0))
  g1.stroke(255);
  g1.endDraw();

  g2 = createGraphics(SIDE, SIDE);
  g2.beginDraw();
  g2.clear();//more than 2.0b8 (If less than 2.0b7 background(0, 0, 0, 0))
  g2.stroke(255);
  g2.endDraw();
}
void draw() {
  g1.beginDraw();
  x =g1.width/2+ random(-1, 1)*RATIO;
  y =g1.height/2+ random(-1, 1)*RATIO;
  g1.point(x, y);
  g1.endDraw();
  image(g1, 0, 0);

  g2.beginDraw();
  x =g2.width/2+ randomGaussian()*RATIO;//more than 2.0b8
  y =g2.height/2+ randomGaussian()*RATIO;//more than 2.0b8
  g2.point(x, y);
  g2.endDraw();
  image(g2, width/2, 0);

  line(width/2, 0, width/2, height);
}

final int RATIO = 10;
float x, y;

void setup() {
  clear();//more than 2.0b8 (If less than 2.0b7 background(0, 0, 0, 0))
  size(200, 200);
  stroke(255);
  frameRate(1000);
}
void draw() {

  //randomGaussian() version
  x =width/2+ randomGaussian()*RATIO;//more than 2.0b8
  y =height/2+ randomGaussian()*RATIO;//more than 2.0b8

  ////random() version
  // x =width/2+ random(-1,1)*RATIO;
  // y =height/2+ random(-1,1)*RATIO;

  point(x, y);
}

Processing Advent Calendar 2012　12月9日企画

12月7日、Processingの新しいバージョンである 2.0 beta 7 がリリースされました。
今回は、特に注目すべきポイントについてご紹介します。

今回のバージョンから、新たに「EXPERIMENTAL」モードが追加されました。
このモードには、コード上のエラーをリアルタイムに通知してくれる機能や、
ブレークポイントを指定してデバッグできる機能など、
スケッチ制作を強力にサポートしてくれる機能が搭載されています。



エラー箇所を波線で通知してくれたり、コンソール部にエラーの種類や場所を示してくれるようになりました。
複数箇所のエラーもまとめて通知してくれるので、実行と修正を何度も繰り返す手間を省いてくれます。
また、インスペクタでの変数修正にも対応し、ますます使いやすくなりました。
なお、OSによっては動作が異なるものもあるようです。

また、コードのハイライターも変更され、
鮮やかなハイライターでのコーディングが可能となりました。
上の画像でも、「hight」の文字色がピンク色になっているなど、
変更点が見られます。
EXPERIMENTALモードとあわせて、スケッチ制作がさらに快適になりそうです。

さらに、弧を描くための関数「arc」に、弧のモードを選択するための引数を記述できるようになりました。



左から、OPENモード、CHORDモード、PIEモードです。
コードは以下のとおりです。

void setup() {
  size(360, 150);
  smooth();

  noLoop();
}

void draw() {
  int num = 4;
  int rad = 360/num;
  int arc_w = 80;
  int arc_h = 80;

  for (int i = 1;i <= num;i++) {
    if (i % 2 == 0) {
      arc(60, height/2, arc_w, arc_h, radians(rad * (i-1)), radians(rad * i), OPEN);
      arc(180, height/2, arc_w, arc_h, radians(rad * (i-1)), radians(rad * i), CHORD);
      arc(300, height/2, arc_w, arc_h, radians(rad * (i-1)), radians(rad * i), PIE);
    }
  }
}

clip(x,y,width,height);
noClip();

void mouseEntered() {
  loop();
}
void mouseExited() {
  noLoop();
}

• クリッピング領域の設定&マウスクリックで解除
• カーソルがキャンバスの外にある時にはProcessingを止める
• ellipseをarcに変更してarcをPIEモードでパックマンみたいに変更

int rad = 60;        
float xpos, ypos;        

float xspeed = 2.8;  
float yspeed = 2.2;  

int xdirection = 1;  
int ydirection = 1;  

boolean clip = true;//add for clip();//★クリッピングを反転させるためのフラグ値

void setup() 
{
  size(640, 360);
  noStroke();
  frameRate(30);
  ellipseMode(RADIUS);
  
  xpos = width/2;
  ypos = height/2;
  //background(102);//★バックグラウンドを描かないでクリッピングすると初期画面のグレーになるので、正常に表示させるにはこのコメントを外します。
  clip(width/5*1, height/5*1, width/5*3, height/5*3);//★クリップ領域を設定
}
void mousePressed() {//★クリックアクションを追加
  if (clip) {
    noClip();//★クリップ領域を解除
  }
  else {
    clip(width/5*1, height/5*1, width/5*3, height/5*3);//★クリップ領域を設定
  }
  clip = !clip;
}
void mouseEntered() {//★カーソルがキャンバス内にある時
  loop();//draw()を回す
}
void mouseExited() {//★カーソルがキャンバス外に出た時
  noLoop();//draw()を止める
}
void draw() 
{
  background(102);

  xpos = xpos + ( xspeed * xdirection );
  ypos = ypos + ( yspeed * ydirection );

  if (xpos > width-rad || xpos < rad) {
    xdirection *= -1;
  }
  if (ypos > height-rad || ypos < rad) {
    ydirection *= -1;
  }

  arc(xpos, ypos, rad, rad, radians(30), radians(330), PIE);//★最後の引数"PIE"を追加しました。よろしければ"CHORD"などもお試しください、デフォルトは"OPEN"です
}